Mac Expert 1995 Winter/Mac Expert - Winter 95.iso/Les fichiers/Communications/AppleTalk Remote access/Scripts ARA ƒ/Hayes V-Series 9600/Hayes V-Series 9600

Text File | 1991-12-17 | 3.0 KB | 195 lines | [mlts/slnk]

! "Hayes V-Series 9600 - 11/14/91"
@ORIGINATE
@ANSWER
!
@LABEL 1
serreset 19200, 0, 8, 1
HSReset 0 1 0 0 0 0
!
! first recall the factory configuration
!
matchclr
settries 0
matchstr 1 3 "OK\13\10"
@LABEL 2
write "AT&F\13"
matchread 30
inctries
iftries 2 59
jump 2
!
! Next, Set carrier timing, echo off, set flow control
!
@LABEL 3
matchstr 1 4 "OK\13\10"
write "ATS7=60S10=100E0&K3\13"
matchread 30
jump 59
!
! Next, set DTR to ignore
!
@LABEL 4
matchstr 1 5 "OK\13\10"
matchstr 2 5 "ERROR\13\10"
write "AT&D0\13"
matchread 30
!
! If speaker on flag is true, jump to label 8.  Else turn off the speaker
@LABEL 5
matchclr
ifstr 2 8 "1"
matchstr 1 8 "OK\13\10"
write "ATM0\13"
matchread 30
jump 59
!
! The modem is ready.  So enable answering, or originate a call
!
@LABEL 8
ifANSWER 30
note "Dialing ^1" 3
write "ATS0=0DT^1\13"
!
@LABEL 9
matchstr  1 11 "CONNECT 1200\13\10"
matchstr  2 12 "CONNECT 2400\13\10"
matchstr  3 13 "CONNECT 4800\13\10"
matchstr  4 14 "CONNECT 9600\13\10"
matchstr  5 15 "CONNECT 19200\13\10"
matchstr  6 50 "NO CARRIER\13\10"
matchstr  7 50 "ERROR\13\10"
matchstr  8 52 "NO DIALTONE\13\10"
matchstr  9 53 "BUSY\13\10"
matchstr 10 54 "NO ANSWER\13\10"
matchread 700
jump 59
!
@LABEL 11
note "Communicating at 1200 bps." 2
serreset 1200, 0, 8, 1
jump 16
!
@LABEL 12
note "Communicating at 2400 bps." 2
serreset 2400, 0, 8, 1
jump 16
!
@LABEL 13
note "Communicating at 4800 bps." 2
serreset 4800, 0, 8, 1
jump 16
!
@LABEL 14
note "Communicating at 9600 bps." 2
serreset 9600, 0, 8, 1
jump 16
!
@LABEL 15
note "Communicating at 19.2 kbps." 2
serreset 19200, 0, 8, 1
!
@LABEL 16
ifANSWER 17
pause 30
@LABEL 17
exit 0
!
! @ANSWER
! Set up the modem to answer on 2nd ring
@LABEL 30
write "ATS0=2\13"
matchstr 1 31 "OK\13\10"
matchread 30
jump 59
!
@LABEL 31
matchstr 1  32 "RING\13\10"
matchstr 2  11 "CONNECT 1200\13\10"
matchstr 3  12 "CONNECT 2400\13\10"
matchstr 4  13 "CONNECT 4800\13\10"
matchstr 5  14 "CONNECT 9600\13\10"
matchstr 6  15 "CONNECT 19200\13\10"
matchstr 7  50 "NO CARRIER\13\10"
matchstr 8  50 "ERROR\13\10"
matchstr 9  52 "NO DIALTONE\13\10"
matchstr 10 53 "BUSY\13\10"
matchstr 11 54 "NO ANSWER\13\10"
matchread 700
jump 31
!
@LABEL 32
userhook 1
note "Answering phone…" 2
jump 31
!
! 50: error messages
!
@LABEL 50
exit -6021
!
@LABEL 52
exit -6020
!
@LABEL 53
exit -6022
!
@LABEL 54
exit -6023
!
@LABEL 59
exit -6019
!
! Hang up the modem
!
@HANGUP
@LABEL 60
settries 0
@LABEL 61
write "ATH0\13"
matchclr
matchstr 1 64 "OK\13\10"
matchstr 2 63 "NO CARRIER\13\10"
matchstr 3 64 "ERROR\13\10"
matchread 15
inctries
iftries 3 64
! no response, try escape sequence
write "+++"
matchclr
matchstr 1 62 "OK\13\10"
matchread 18
! No response from modem, send modem reset command
!
write "ATZ\13\10"
pause 10

jump 61
!
@LABEL 62
matchclr
matchstr 1 64 "OK\13\10"
matchstr 2 63 "NO CARRIER\13\10"
write "ATH0\13"
matchread 50
jump 61
!
@LABEL 63
pause 45
flush
!
! Recall the factory settings
!
@LABEL 64
matchclr
matchstr 1 65 "OK\13\10"
write "AT&F\13"
matchread 30
!
@LABEL 65
matchstr 1 66 "OK\13\10"
write "ATS0=0\13"
matchread 30
!
@LABEL 66
exit 0